# basic stuff
TARGET = desafinado
VERSION = 0.0.1
TEMPLATE = app
SOURCES += main.cpp \
    mainwindow.cpp \
    record.cpp \
    calculate.cpp \
    pitchmeter.cpp \
    settingswindow.cpp
HEADERS += mainwindow.h \
    record.h \
    calculate.h \
    pitchmeter.h \
    settingswindow.h
FORMS += mainwindow.ui \
    settingswindow.ui
RESOURCES += desafinado.qrc
TRANSLATIONS += desafinado_de.ts
DISTFILES += README COPYING TODO \
    graphic/desafinado* \
    desafinado.pod desafinado.1 \
    desafinado.desktop

qtlibdir = $$[QT_INSTALL_LIBS]
exists( $$qtlibdir/libQtMultimediaKit.so* ) {
	## 4.7 (debian): builds, explodes with pulseaudio (!) error
	## works when pulseaudio is installed
	message( "Configuring for QtMultimediaKit ..." )
	# http://doc.qt.nokia.com/qtmobility-1.1.0/all-examples.html#multimedia
	CONFIG += mobility
	MOBILITY += multimedia
} else {
	## default, works with 4.6 (debian), 4.7 (vanilla), 
	## 4.7.0 (maemo5), 4.7.2 (maemo5 + cssu), 4.7.1 (win32)
	message( "Configuring for QtMultimedia ..." )
	QT += multimedia
}

# profiling
# CONFIG += profile
profile {
    QMAKE_CXXFLAGS_DEBUG += -pg
    QMAKE_LFLAGS_DEBUG += -pg
    QMAKE_CXXFLAGS += -pg
    QMAKE_LFLAGS += -pg
}

# set a sensible default
unix: isEmpty( PREFIX ) {
	PREFIX = /usr/local
}

# install target
unix: {
	DEST = $$INSTALL_ROOT$$PREFIX
	BINDIR = $$DEST/bin
	DOCDIR = $$DEST/share/doc/$$TARGET
	MAN1DIR = $$DEST/share/man/man1
	ICONDIR = $$DEST/share/pixmaps
	APPDIR = $$DEST/share/applications

	DOCS = README TODO
	MANPAGES = $${TARGET}.1
	ICONS = graphic/$${TARGET}.png
	XDG = $${TARGET}.desktop

	target.path = $$BINDIR
	docs.files = $$DOCS
	docs.path = $$DOCDIR
	man1.files = $$MANPAGES
	man1.path = $$MAN1DIR
	man1.CONFIG = no_check_exist
	man1.depends = manpage
	icon.files = $$ICONS
	icon.path = $$ICONDIR
	icon.CONFIG = no_check_exist
	icon.depends = icons
	xdg.files =$$XDG
	xdg.path = $$APPDIR

	INSTALLS += target docs man1 icon xdg
}

# make dist is ... weird --> make release
release.depends = tarball

tarball.target = $${TARGET}-$${VERSION}.tar.gz
tarball.commands = \
	$(DEL_FILE) -r $${TARGET}-$${VERSION} ; \
	$(MKDIR) -p $${TARGET}-$${VERSION} ; \
	$(COPY_DIR) --parents $$FORMS $$RESOURCES $$TRANSLATIONS $$SOURCES $$HEADERS $$DISTFILES $${TARGET}.pro $${TARGET}-$${VERSION}/ ; \
	tar cfz $$tarball.target $${TARGET}-$${VERSION} ; \
	$(DEL_FILE) -r $${TARGET}-$${VERSION}
tarball.depends = manpage icons

manpage.target = $${TARGET}.1
manpage.commands = pod2man --center=\"Musical instrument tuner\" --release=\"Version $${VERSION}\" $${TARGET}.pod > $${TARGET}.1
manpage.depends = $${TARGET}.pod

icons.target = graphic/$${TARGET}.png
icons.commands = convert graphic/$${TARGET}.svg graphic/$${TARGET}.png
icons.depends = graphic/$${TARGET}.svg

QMAKE_EXTRA_TARGETS += tarball manpage icons release
QMAKE_DISTCLEAN += $${TARGET}.1 graphic/$${TARGET}.png